Trying fully free RPG

Thanks to the guys at RZKH.DE I was able to try the new fully free RPG this weekend. The latest Technology Refreshes to IBM i 7.2, TR3, and 7.1, TR11, finally brought what can only be described a completely free RPG. Even though "all free" RPG that came in IBM i 7.1 TR7, it was still restricted to be used between the eighth and 80th columns. With these TRs it is no limited by any column restrictions, and I can use any position from the first to the last of the source member.

I thought it would be a good idea for me to share my first impressions of what I have found using "fully free" RPG, covering what I think is good and not so good.

The RZKH.DE informed me that the PTFs necessary for "fully free" was not part of the PTFs they downloaded for the TR3 upgrade to the IBM i 7.2 server.

You will need to have the following PTFs applied on your server to be able to use this:

IBM i release	PTF number	Description
7.2	SI58137	RPG compiler, current target release
	SI58110	RPG compiler, previous target release
	Group SF99702 level 9	SQL precompiler
7.1	SI58136	RPG compiler, current target release
	Group SF99701 level 38	SQL precompiler

There is no previous release support for 7.1

You can check the status of these PTFs on your server using the SQL View PTF_LOD. If I wanted to check if the RPG PTFs have been loaded to an IBM i 7.2 server I could use the following SQL statement:

SELECT PTFID,LOADSTAT FROM QSYS2/PTF_INFO WHERE PTFID IN ('SI58137','SI58110')

For more information on this View see the post Quick way to find if PTF present and applied.

When coding "fully free" RPG I need to start with the compiler directive **FREE, starting in the first position of the source member. The code of all subsequent lines can start anywhere on the source member's line. See the example below:

...+... 1 ...+... 2 ...+... 3 ...+... 4 ...+... 5 ...+... 6 ...+... 7 01 **FREE 02 dcl-s Message char(30) inz('This is great!') ; 03 dsply Message ; 04 Message = 'Now I can really be FREE!' ; 05 dsply Message ; 06 *inlr = *on ;

The **FREE compiler directive does not have to be upper case, I can use **free too.

What happens when I mix free format RPG with fixed format? For example:

...+... 1 ...+... 2 ...+... 3 ...+... 4 ...+... 5 ...+... 6 ...+... 01 **FREE 02 dcl-s Incoming char(30) ; 03 C *entry plist 04 C parm InComing 05 dsply Incoming ; 06 *inlr = *on ;

This code does not compile, giving me the message below for line 3, as fixed format code cannot be entered after the **FREE.

RNF5347 30 An assignment operator is expected with the EVAL operation.

But fixed format can be used before the **FREE, see below. But any free format code before the **FREE is restricted to the range of the eighth to the 80th column, see line 1.

...+... 1 ...+... 2 ...+... 3 ...+... 4 ...+... 5 ...+... 6 01 dcl-s Incoming char(30) ; 02 C *entry plist 03 C parm InComing 04 **FREE 05 dsply Incoming ; 06 *inlr = *on ;

With "fully free" RPG I am no longer restricted to use a source file a record length of 112. I can create the largest source file possible, record length of 240, and use that:

CRTSRCPF FILE(QTEMP/QTEMPSRC) RCDLEN(240)

In the example below line 5 starts are the 205 position of the source member. I would not recommend making source files with such large record lengths, I just wanted to show what was possible.

...+... 1 ...+... 2 ... // 200 ...+... 1 ...+... 2 ...+... 01 **free 02 dcl-s Message char(30) ; 03 Message = 'First line' ; 04 dsply Message ; 05 Message = 'Second line' ; 06 dsply Message ; 07 *inlr = *on ;

I did find documented a way to get around not being able to use fixed format code after the **FREE. It described you would have to use external members containing the fixed format code, what would be copied into a "fully free" member using either /COPY or /INCLUDE. For example:

01 **free 02 dcl-s Incoming char(30) ; 03 /copy mylib/devsrc,rpgcpy1 04 dsply Incoming ; 05 *inlr = *on ;

When compiled the external member is copied into my member. If I look at compile listing I see:

**free dcl-s Incoming char(30) ; /copy mylib/devsrc,rpgcpy1 <--------------- Source Specifications -----------------> *------------------------------------------------------* * RPG member name . . . . . : RPGCPY1 * * External name . . . . . . : MYLIB/DEVSRC(RPGCPY1) * * Last change . . . . . . . : DD/DD/DD TT:TT:TT * *------------------------------------------------------* C *entry plist C parm Incoming dsply Incoming ; *inlr = *on ;

This is another reminder from IBM that it is time to let go of fixed format code, and embrace the free format equivalents.

I think this move to finally free RPG is a big step forward for the language, finally removing it from the restrictions imposed by punch cards all those many years ago. I can see that the inability to insert fixed format code into a "fully free" member will stop some from adopting this, which is a shame and I wish that IBM would have allowed fixed format lines after the **FREE.

Will you start using "fully free" RPG? Let me know your thoughts in the comments below.

 

You can learn more about the **FREE compiler directive from the IBM website here.

 

This article was written for IBM i 7.2 TR3 and 7.1 TR11, and later releases.